다음 그림과 같이 미크로틱 라우터 1대와 미크로틱 스위치 2대를 사용하여 VLAN을 구성하려고 합니다.
라우터 (CCR1009)에 스위치 1대 (CRS326-1)를 연결하는 경우의 VLAN 인터페이스 설정하는 방법은 이해를 했는데요,
윗 그림과 같이, 라우터 (CCR1009)에 스위치 2대 (CRS326-1, CRS326-2)를 연결하는 경우의 VLAN 인터페이스 설정하는 방법은 잘 모르겠습니다.
라우터와 스위치 CCR326-1간은 ether2~ether1 연결이구요
라우터와 스위치 CCR326-2간에는 sfp+1~sfp+1 연결입니다.
어쩌다보니 네트웍 전문지식 없이 업무를 맡게돼서 많이 헤메고 있습니다.
어떻게 해결할 수 있는지 도움 부탁드립니다.
고맙습니다.
말씀주신대로, 스위치 1대 (CRS326-1) 있을경우의 VLAN 인터페이스 설정하는방법으로, 스위치 CRS326-2의 VLAN인터페이스 설정을 시도했습니다만,,, 지식이 짧아서 여기서 막혔습니다. ㅠㅠ
제가 막힌 부분을 구체적으로 말씀드리면;
Winbox를 이용했습니다
스위치 1대 (CRS326-1) 연결하는 경우의 VLAN인터페잇 설정
라우터 CCR1009 OS에서
메뉴에서 interface > Interface List창이 열림 > VLAN탭 에서
+버튼 > New Interface창이 열림
Name : vlan-10 입력
VLAN ID : 10 입력
Interface: ether2 선택 (트렁크포트)
Apply, OK 버튼 누름
+버튼 > New Interface창이 열림
Name : vlan-20 입력
VLAN ID : 20 입력
Interface: ether2 선택 (트렁크포트)
Apply, OK 버튼 누름
+버튼 > New Interface창이 열림
Name : vlan-99 입력
VLAN ID : 99 입력
Interface: ether2 선택 (트렁크포트)
Apply, OK버튼 누름
스위치 1대 (CRS326-2)를 추가 연결하는 경우의 VLAN 인터페잇 설정
라우터CCR1009 OS에서
메뉴에서 interface > Interface List창이 열림 > VLAN탭 에서
+버튼 > New Interface창이 열림
Name : vlan-10 입력
VLAN ID : 10 입력
Interface: sfp+1 선택 (트렁크포트)
Apply, OK버튼 누름
여기서 Name: Vlan-10 이 중복돼서 사용할 수 없다는 에러가 발생합니다.
그래서 이름을 다르게 변경 했더니 (다른것은 동일) 진행은 됩니다.
Name : vlan-10-1입력
VLAN ID : 10 입력
Interface: sfp+1 선택 (트렁크포트)
Apply, OK버튼 누름
Name은 다르고, VLAN ID는 동일한데, 이게 맞는것인지 잘 모르겠습니다.
목적은 건물 위치와 상관없이 같은 부서 (Vlan이름이 같은)끼리 통신하자는것입니다.
어떻게 해야 하는지 도움 부탁 드립니다.
고맙습니다.
이것 보시고 설정값을 택스트로 받아서 올려주시면 확인이 훨씬 수월할 것입니다..
https://wiki.mikrotik.com/wiki/Manual:Basic_VLAN_switching
https://help.mikrotik.com/docs/display/ROS/VLAN#VLAN-Layer3VLANexamples
그러면,
스위치 CRS326-2 를 라우터에서 떼어 내서 스위치CRS326-1에 연결하고,
스위치 CRS326-1 을 통해 라우터에 접속되게 하라는 말씀으로 이해하면 되겠는지?
주신 조언을 다음과 같은 방법으로 이해 했습니다만, 맞은 방법인지 확인 부탁드립니다.
1. 라우터에서 브릿지 생성 (이름: bridge_trunk)
2. bridge_trunk에 포트 추가: ether2 (CRS326-1용), sfp+ (CRS326-2용)
3. Vlan interface 설정 창에서,
name: vlan-10
VLANID: 10
interface: bridge_trunk
맞는 방법일까요?
마지막에는 VLAN20에 대한 인터페이스도 만들어주세요.
#Router에 대한 VLAN, inter-VLAN 라우팅 예제
#ether1에 인터넷 연결(dhcp-client)
#ether2는 VLAN10에 대해 untag된 access port
#ether3은 VLAN20에 대해 untag된 access port
#VLAN99는 management용, 실제 포트는 사용하지 않음
#ether4,ether5는 VLAN10, 20, 99에 대한 trunk port
#bridge1상에 VLAN설정, VLAN10, VLAN20, VLAN99에 대한 인터페이스 작성
#VLAN10 인터페이스의 IP : 192.168.10.1/24
#VLAN20 인터페이스의 IP : 192.168.20.1/24
#VLAN99 인터페이스의 IP : 192.168.99.1/24
#192.168.10.0/24, 192.168.20.0/24, 192.168.99.0/24 을 intenal이라는 그룹으로 묶어서 NAT의 masquerade에 활용
#브리지작성, 세팅중에는 VLAN 필터링 하지 않는 것을 권장
/interface bridge
add ingress-filtering=no name=bridge1 vlan-filtering=no
#브리지에 ether2~5 포트를 추가, access port로 사용할 포트는 pvid에 untag할 VID를 명기
/interface bridge port
add bridge=bridge1 interface=ether2 pvid=10
add bridge=bridge1 interface=ether3 pvid=20
add bridge=bridge1 interface=ether4
add bridge=bridge1 interface=ether5
#브리지 VLAN테이블 작성
#VLAN10에 대해서는 ether2에서만 untag, ether3~5, bridge1에 대해서는 tag
#VLAN20에 대해서는 ether3에서만 untag, ether2,ether4~5, bridge1에 대해서는 tag
#VLAN99에 대해서는 ether2~5, bridge1에 대해서 tag
/interface bridge vlan
add bridge=bridge1 tagged=bridge1,ether2,ether4,ether5 untagged=ether3 vlan-ids=20
add bridge=bridge1 tagged=bridge1,ether3,ether4,ether5 untagged=ether2 vlan-ids=10
add bridge=bridge1 tagged=bridge1,ether2,ether3,ether4,ether5 vlan-ids=99
#각 VLAN 인터페이스 작성
/interface vlan
add interface=bridge1 name=vlan10 vlan-id=10
add interface=bridge1 name=vlan20 vlan-id=20
add interface=bridge1 name=vlan99 vlan-id=99
#각 VLAN 인터페이스에 주소 부여
/ip address
add address=192.168.10.1/24 interface=vlan10 network=192.168.10.0
add address=192.168.20.1/24 interface=vlan20 network=192.168.20.0
add address=192.168.99.1/24 interface=vlan99 network=192.168.99.0
#각 VLAN 인터페이스를 바라보는 DHCP 서버 작성, 99는 작성하지 않음
/ip pool
add name=dhcp_pool0 ranges=192.168.10.2-192.168.10.254
add name=dhcp_pool1 ranges=192.168.20.2-192.168.20.254
/ip dhcp-server
add address-pool=dhcp_pool0 interface=vlan10 name=dhcp1
add address-pool=dhcp_pool1 interface=vlan20 name=dhcp2
/ip dhcp-server network
add address=192.168.10.0/24 dns-server=8.8.8.8 gateway=192.168.10.1
add address=192.168.20.0/24 dns-server=8.8.8.8 gateway=192.168.20.1
#192.168.10.0/24, 192.168.20.0/24을 intenal이라는 그룹으로 묶기
/ip firewall address-list
add address=192.168.10.0/24 list=internal
add address=192.168.20.0/24 list=internal
add address=192.168.99.0/24 list=internal
#src주소리스트가 internal이고, 외부로 나가는 트래픽에 대하여 NAT처리
/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1 src-address-list=internal
#외부주소는 DHCP 클라이언트 설정
/ip dhcp-client
add interface=ether1
#브리지 VLAN 필터링 활성화
/interface bridge
set bridge1 vlan-filtering=yes
#스위치설정
#Router에 대한 VLAN, inter-VLAN 라우팅 예제
#ether1은 VLAN10, 20, 99에 대한 trunk port
#ether2, ether3은 VLAN10에 대해 untag된 access port
#ether4, ether5은 VLAN20에 대해 untag된 access port
#VLAN99는 management용, 실제 포트는 사용하지 않음
#bridge1상에 VLAN설정, VLAN10, VLAN20, VLAN99에 대한 인터페이스 작성
#VLAN99 인터페이스의 IP : 192.168.99.2/24
#브리지작성, 세팅중에는 VLAN 필터링 하지 않는 것을 권장
/interface bridge
add ingress-filtering=no name=bridge1 vlan-filtering=no
#브리지에 ether1~5 포트를 추가, access port로 사용할 포트는 pvid에 untag할 VID를 명기
/interface bridge port
add bridge=bridge1 interface=ether1
add bridge=bridge1 interface=ether2 pvid=10
add bridge=bridge1 interface=ether3 pvid=10
add bridge=bridge1 interface=ether4 pvid=20
add bridge=bridge1 interface=ether5 pvid=20
#브리지 VLAN테이블 작성
#VLAN10에 대해서는 ether2,3에서만 untag, ether1, ether4~5, bridge1에 대해서는 tag
#VLAN20에 대해서는 ether4,5에서만 untag, ether1~3, bridge1에 대해서는 tag
#VLAN99에 대해서는 ether1~5, bridge1에 대해서 tag
/interface bridge vlan
add bridge=bridge1 tagged=bridge1,ether1,ether4,ether5 untagged=ether2,ether3 vlan-ids=10
add bridge=bridge1 tagged=bridge1,ether1,ether2,ether3 untagged=ether4,ether5 vlan-ids=20
add bridge=bridge1 tagged=bridge1,ether1,ether2,ether3,ether4,ether5 vlan-ids=99
#VLAN99 인터페이스 작성
/interface vlan
add interface=bridge1 name=vlan99 vlan-id=99
#VLAN99 인터페이스에 주소 부여
/ip address
add address=192.168.99.2/24 interface=vlan99 network=192.168.99.0
#게이트웨이 입력
/ip route
add disabled=no dst-address=0.0.0.0/0 gateway=192.168.99.1
#DNS서버 입력
/ip dns
set servers=8.8.8.8
#브리지 VLAN 필터링 활성화
/interface bridge
set bridge1 vlan-filtering=yes
와~ 감동입니다!
많은 도움이 될 것 같습니다
더불어 많은 것 배웁니다.
감사합니다.