친구가 물어봐서 한번 만들어 본겁니다.

필요한게 일하는 용도랑 기숙사 용도로 포트를 분리하고, 기숙사에서 낮시간동안 못쓰게 오후 5시부터 아침 8시까지만 인터넷 잘되도록 설정.. 이건데요.. 잘된다는게...10메가 제한을 걸었습니다. 낮동안은 64케이 제한..뭐 거의 포기해야죠 요새같아선..

그리고 신버젼에선 요일별 설정도 가능하니 주말용도 만들어 볼만 할겁니다. 이건 안했습니다.

간단히 설명하면 750이나 450 시리즈 같은 5포트 미크로틱 라우터에 일단 ros 6.15버젼으로 만들었습니다.
아무런 기본설정이 없는 상태를 기준으로 만들었으니 적용하시려면 리셋하고 기본 설정을 지우셔야 합니다.

1. 포트1번에 dhcp-client 로 공인아이피 받아오고(고정아이피면 고정으로 설정해야죠)

/ip dhcp-client
add default-route-distance=0 dhcp-options=hostname,clientid disabled=no interface=ether1

2. 브릿지 하나 만들어서 Work 라 이름짓고 포트 2,3,4번을 할당하고 아이피는 192.168.0.0/24 할당하고 dhcp-server 세팅

/interface bridge
add l2mtu=1520 name=Work
/interface bridge port
add bridge=Work interface=ether2
add bridge=Work interface=ether3
add bridge=Work interface=ether4
/ip address
add address=192.168.0.1/24 comment=Work interface=Work network=192.168.0.0
/ip pool
add name=dhcp_pool1 ranges=192.168.0.2-192.168.0.254
/ip dhcp-server
add address-pool=dhcp_pool1 disabled=no interface=Work name=dhcp1
/ip dhcp-server network
add address=192.168.0.0/24 gateway=192.168.0.1

3. 포트 5번은 기숙사용으로 만들고 아이피는 192.168.1.0/24 할당 하고 dhcp-server 세팅

/ip address
add address=192.168.1.1/24 comment=Home interface=ether5 network=192.168.1.0
/ip pool
add name=dhcp_pool2 ranges=192.168.1.2-192.168.1.254
/ip dhcp-server
add address-pool=dhcp_pool2 disabled=no interface=ether5 name=dhcp2
/ip dhcp-server network
add address=192.168.1.0/24 gateway=192.168.1.1

4. 기숙사용과 업무용 모두 1번에 대해 masqurade 설정

/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1 

여기까진 그냥 일반 공유기 세팅이고..

5. 심플큐를 두개 만들어서 낮용은 64k 정도로 제한하고 밤용은 10메가로 제한

/queue simple
add limit-at=64k/64k max-limit=64k/64k name=Day target=192.168.1.0/24,ether5
add limit-at=10M/10M max-limit=10M/10M name=Night target=192.168.1.0/24,ether5 

6. ntp 클라이언트 만들어서 시간동기화 하고 한국 현지 시간으로 맞추고

/system ntp client
set enabled=yes primary-ntp=213.239.154.12 secondary-ntp=213.249.66.35
/system clock
set time-zone-name=Asia/Seoul

7. 스크립트 를 두개 만듭니다..

하나는 낮용으로 낮용 큐를 켜고 밤용 큐를 끄는거

또하나는 밤용으로 낮용 큐를 끄고 밤용 큐를 키는거

/system script
add name=Day policy=ftp,reboot,read,write,policy,test,winbox,password,sniff,sensitive,api source="/queue simple enable Day; /queue simple disable Night"
add name=Night policy=ftp,reboot,read,write,policy,test,winbox,password,sniff,sensitive,api source="/queue simple enable Night; /queue simple disable Day"

8. 마지막으로 스케쥴러 두개를 만들어서 낮용 스크립트는 매일 아침 8시에 실행하고

밤용 스크립트는 오후 5시에 실행하게 만듭니다.

/system scheduler
add interval=1d name=Day on-event=Day policy=ftp,reboot,read,write,policy,test,winbox,password,sniff,sensitive,api start-date=jul/04/2014 start-time=08:00:00
add interval=1d name=Night on-event=Night policy=ftp,reboot,read,write,policy,test,winbox,password,sniff,sensitive,api start-date=jul/04/2014 start-time=17:00:00

어디 유용하게 쓰실데가 있으시길 ...